From d427dea70a2b733e88ea3681bd0666d24f16531a Mon Sep 17 00:00:00 2001
From: Yuya KAMATAKI <kamataki@rumginger.org>
Date: Thu, 12 Feb 2026 03:03:19 +0900
Subject: [PATCH] support for arch linux

---
 PKGBUILD         | 46 ++++++++++++++++++++++++++++++++++++++++++++++
 tauclock.desktop |  9 +++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 PKGBUILD
 create mode 100644 tauclock.desktop

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..a49438b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+pkgname=tauclock-git
+pkgver=0.1.0.r0.g0000000
+pkgrel=1
+pkgdesc="Keyboard-driven clock, alarm, timer, and stopwatch desktop app built with Tauri"
+arch=('x86_64')
+url="https://git.rumginger.org/kamat/tauclock.git"
+license=('MIT')
+depends=(
+  'gtk3'
+  'webkit2gtk-4.1'
+)
+makedepends=(
+  'cargo'
+  'git'
+  'rust'
+)
+source=("git+${url}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/tauclock/src-tauri"
+  local version
+  version="$(grep -m1 '^version = ' Cargo.toml | cut -d'"' -f2)"
+  printf '%s.r%s.g%s' "${version}" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${srcdir}/tauclock/src-tauri"
+  export CARGO_TARGET_DIR="${srcdir}/target"
+  cargo build --release --locked
+}
+
+package() {
+  cd "${srcdir}/tauclock"
+
+  install -Dm755 "${srcdir}/target/release/tauclock" \
+    "${pkgdir}/usr/bin/tauclock"
+  install -Dm644 "tauclock.desktop" \
+    "${pkgdir}/usr/share/applications/tauclock.desktop"
+  install -Dm644 "src-tauri/icons/128x128.png" \
+    "${pkgdir}/usr/share/icons/hicolor/128x128/apps/tauclock.png"
+  install -Dm644 "LICENSE" \
+    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
diff --git a/tauclock.desktop b/tauclock.desktop
new file mode 100644
index 0000000..2edd3c6
--- /dev/null
+++ b/tauclock.desktop
@@ -0,0 +1,9 @@
+[Desktop Entry]
+Type=Application
+Name=TauClock
+Comment=Keyboard-driven clock, alarm, timer, and stopwatch
+Exec=tauclock
+Icon=tauclock
+Terminal=false
+Categories=Utility;Clock;
+StartupNotify=true